9.13　レイヤの自動移動（その１）

class SimpleMover
{
    // メンバ変数
    var layer;     // 動かすレイヤへの参照
    var lLimit;    // 左方向にこの位置まで移動可能
    var rLimit;    // 右方向にこの位置まで移動可能
    var moveWidth; // 移動可能な幅
    var speed;     // 移動速度(ピクセル／秒）
    var startTime; // 移動開始時刻
    var moving;    // 移動しているか

    // コンストラクタ（引数に動かしたいレイヤを指定します）
    function SimpleMover(layer)
    {
        this.layer = layer; // レイヤへの参照を保存しておきます
        moving = false; // 初期状態では移動していないので false を代入します
    }

    // デストラクタ
    function finalize()
    {
        stopMove(); // 無効化される前にレイヤの移動を停止します
    }

    // レイヤの移動を開始します
    function beginMove(speed = 200)
    {
        // 移動可能な左端の座標を計算します
        lLimit = -layer.width;
        // 移動可能な右端の座標を計算します
        rLimit = kag.scWidth;
        // 移動可能な幅を計算します
        moveWidth = rLimit - lLimit;
        // レイヤを初期位置（左端）に移動します
        layer.setPos(lLimit, (kag.scHeight - layer.height) \ 2);
        // 移動速度を設定します
        this.speed = speed;
        // コンティニュアスハンドラを追加します
        System.addContinuousHandler(handler);
        // 移動開始時刻を記録します
        startTime = System.getTickCount();
        // レイヤの移動が開始するので moving を true にします
        moving = true;
    }

    // レイヤの移動を停止します
    function stopMove()
    {
        if(moving) // レイヤが現在移動中であれば...
        {
            // コンティニュアスハンドラを削除します
            System.removeContinuousHandler(handler);
            // レイヤの移動が停止するので moving を false にします
            moving = false;
        }
    }

    // コンティニュアスハンドラとして呼び出されるメソッド
    function handler(tickCount)
    {
        try
        {
            if(layer isvalid) // レイヤが無効化されていなければ...
            {
                // 移動距離を計算します
                var dist = (tickCount - startTime) * speed \ 1000;
                // レイヤの位置を計算・設定します
                dist %= moveWidth * 2;
                if(dist <= moveWidth)
                    layer.left = lLimit + dist;
                else
                    layer.left = rLimit - (dist - moveWidth);
            }
        }
        catch(e)
        {
            // try ブロック内で例外が発生した場合はレイヤの移動を停止します
            stopMove();
            // 再び例外を投げます
            throw e;
        }
    }
}