Section 4.4　画像のコピー（その１）

[iscript]

class DatePlugin extends KAGPlugin
{
    var imgLay;   // 日付表示に使う画像用のレイヤ
    var foreLay;  // 表画面用のレイヤ
    var backLay;  // 裏画面用のレイヤ
    var chWidth;   // 各文字（数字、"/"）の幅
    var chHeight;  // 各文字の高さ

    // コンストラクタ
    function DatePlugin()
    {
        super.KAGPlugin();  // スーパークラスのコンストラクタを呼び出します

        // 日付表示に使う画像用のレイヤを作ります
        imgLay = new Layer(kag, kag.fore.base);  // 表画面の背景レイヤを親レイヤにします
        imgLay.loadImages("date_char");  // 日付表示に使う画像を読み込みます

        chWidth = imgLay.imageWidth \ 11;  // 文字の幅を代入します
        chHeight = imgLay.imageHeight;     // 文字の高さを代入します

        // 表画面用のレイヤを作ります
        foreLay = new Layer(kag, kag.fore.base);  // 表画面の背景レイヤを親レイヤにします
        with(foreLay)
        {
            .setSize(chWidth * 5, chHeight);  // 日付が表示できるようにサイズを設定します
            .setPos(20, 20);  // 位置を (20, 20) に設定します
            .visible = true;  // 表示状態にします
        }

        // 裏画面用のレイヤを作ります
        backLay = new Layer(kag, kag.back.base);  // 裏画面の背景レイヤを親レイヤにします
        with(backLay)
        {
            .setSize(foreLay.width, foreLay.height);  // 表画面のレイヤと同じサイズにします
            .setPos(foreLay.left, foreLay.top);  // 表画面のレイヤと同じ位置にします
            .visible = true;  // 表示状態にします
        }
    }

    // デストラクタ
    function finalize()
    {
        invalidate imgLay;   // 日付表示に使う画像用のレイヤを無効化します
        invalidate foreLay;  // 表画面用のレイヤを無効化します
        invalidate backLay;  // 裏画面用のレイヤを無効化します

        super.finalize();  // スーパークラスのデストラクタを呼び出します
    }

    // レイヤに文字を書き込みます
    function drawChar(layer, char, left, top = 0)
    {
        // imgLay の char 番目の文字の画像を layer にコピーします
        layer.copyRect(left, top, imgLay, chWidth * char, 0, chWidth, chHeight);
    }

    // レイヤに日付を書き込みます
    function drawDate(month, day, fore = true)
    {
        // fore が true なら表、false なら裏画面のレイヤに書き込みます
        var layer = fore ? foreLay : backLay;

        // 以下レイヤに文字を書き込みます
        drawChar(layer, month \ 10, 0);          // 月の10の位
        drawChar(layer, month % 10, chWidth);    // 月の１の位
        drawChar(layer, 10, chWidth * 2);        // ／（スラッシュ）
        drawChar(layer, day \ 10, chWidth * 3);  // 日の10の位
        drawChar(layer, day % 10, chWidth * 4);  // 日の１の位
    }
}

// プラグインオブジェクトを作って kag オブジェクトに登録します
kag.addPlugin(global.date = new DatePlugin());

[endscript]

[return]

foreLay.copyRect(0, 0, imgLay, chWidth, 0, chWidth, chHeight);